autotools: update deprecated macros

see https://www.gnu.org/software/autoconf/manual/autoconf-2.69/html_node/Obsolete-Macros.html

- update AC_HELP_STRING to AS_HELP_STRING
- update AC_TRY_COMPILE to AC_COMPILE_IFELSE
- update AC_TRY_RUN to AC_RUN_IFELSE
- update AC_TRY_LINK to AC_LINK_IFELSE

3 files changed, 20 insertions, 16 deletions

diff --git a/m4/japhar_grep_cflags.m4 b/m4/japhar_grep_cflags.m4
index cf2ea4a5..d0b05f07 100644
--- a/m4/japhar_grep_cflags.m4
+++ b/m4/japhar_grep_cflags.m4
@@ -22,7 +22,8 @@ dnl
 AC_DEFUN([AC_C___ATTRIBUTE__], [
 AC_MSG_CHECKING(for __attribute__)
 AC_CACHE_VAL(ac_cv___attribute__, [
-AC_TRY_COMPILE([
+AC_COMPILE_IFELSE([
+AC_LANG_PROGRAM([[
 #include <stdlib.h>
 static void foo (void) __attribute__ ((unused));
 
@@ -31,12 +32,12 @@ foo (void)
 {
   exit(1);
 }
-],
-[
+]],
+[[
   exit (0);
-],
-ac_cv___attribute__=yes,
-ac_cv___attribute__=no)])
+]])],
+[ac_cv___attribute__=yes],
+[ac_cv___attribute__=no])])
 if test "$ac_cv___attribute__" = "yes"; then
   AC_DEFINE(UNUSED, __attribute__ ((unused)), [define if your compiler has __att
 ribute__ ((unused))])
diff --git a/m4/jh_path_xml_catalog.m4 b/m4/jh_path_xml_catalog.m4
index dd01f165..1f2eff3a 100644
--- a/m4/jh_path_xml_catalog.m4
+++ b/m4/jh_path_xml_catalog.m4
@@ -6,8 +6,8 @@ AC_DEFUN([JH_PATH_XML_CATALOG],
 [
   # check for the presence of the XML catalog
   AC_ARG_WITH([xml-catalog],
-              AC_HELP_STRING([--with-xml-catalog=CATALOG],
-                             [path to xml catalog to use]),,
+              [AS_HELP_STRING([--with-xml-catalog=CATALOG],
+                             [path to xml catalog to use])],,
               [with_xml_catalog=/etc/xml/catalog])
   jh_found_xmlcatalog=true
   XML_CATALOG_FILE="$with_xml_catalog"
diff --git a/m4/libprelude.m4 b/m4/libprelude.m4
index a9ea404c..e1d7a2ba 100644
--- a/m4/libprelude.m4
+++ b/m4/libprelude.m4
@@ -15,8 +15,8 @@ AC_DEFUN([AM_PATH_LIBPRELUDE],
 [dnl
 dnl Get the cflags and libraries from the libprelude-config script
 dnl
-AC_ARG_WITH(libprelude-prefix, AC_HELP_STRING(--with-libprelude-prefix=PFX,
-	    Prefix where libprelude is installed (optional)),
+AC_ARG_WITH(libprelude-prefix, [AS_HELP_STRING([--with-libprelude-prefix=PFX],
+            [Prefix where libprelude is installed (optional)])],
             libprelude_config_prefix="$withval", libprelude_config_prefix="")
 
   if test x$libprelude_config_prefix != x ; then
@@ -52,7 +52,8 @@ dnl Now check if the installed libprelude is sufficiently new. Also sanity
 dnl checks the results of libprelude-config to some extent
 dnl
       rm -f conf.libpreludetest
-      AC_TRY_RUN([
+      AC_RUN_IFELSE([
+      AC_LANG_SOURCE([[
 #include <stdio.h>
 #include <stdlib.h>
 #include <string.h>
@@ -106,7 +107,7 @@ main ()
     }
   return 1;
 }
-],, no_libprelude=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
+]])],[],[no_libprelude=yes],[echo $ac_n "cross compiling; assumed OK... $ac_c"])
        CFLAGS="$ac_save_CFLAGS"
        LIBS="$ac_save_LIBS"
        LDFLAGS="$ac_save_LDFLAGS"
@@ -132,14 +133,16 @@ main ()
        else
           echo "*** Could not run libprelude test program, checking why..."
           CFLAGS="$CFLAGS $LIBPRELUDE_CFLAGS"
-	  LDFLAGS="$LDFLAGS $LIBPRELUDE_LDFLAGS"
+          LDFLAGS="$LDFLAGS $LIBPRELUDE_LDFLAGS"
           LIBS="$LIBS $LIBPRELUDE_LIBS"
-          AC_TRY_LINK([
+          AC_LINK_IFELSE([
+          AC_LANG_PROGRAM([[
 #include <stdio.h>
 #include <stdlib.h>
 #include <string.h>
 #include <libprelude/prelude.h>
-],      [ return !!prelude_check_version(NULL); ],
+]],
+        [[ return !!prelude_check_version(NULL); ]])],
         [ echo "*** The test program compiled, but did not run. This usually means"
           echo "*** that the run-time linker is not finding LIBPRELUDE or finding the wrong"
           echo "*** version of LIBPRELUDE. If it is not finding LIBPRELUDE, you'll need to set your"
@@ -155,7 +158,7 @@ main ()
           echo "*** or that you have moved LIBPRELUDE since it was installed. In the latter case, you"
           echo "*** may want to edit the libprelude-config script: $LIBPRELUDE_CONFIG" ])
           CFLAGS="$ac_save_CFLAGS"
-	  LDFLAGS="$ac_save_LDFLAGS"
+          LDFLAGS="$ac_save_LDFLAGS"
           LIBS="$ac_save_LIBS"
        fi
      fi