configure.ac: rewrite WARN_CFLAGS initialization

As the old machinery was not prepared for adding compiler options
conditionally when the compiler supports them, replace it with
a new machinery that implements this.

* m4/warnings.m4: New file.
* m4/warn_lang_flags.m4: Likewise.
* m4/.gitignore: Add exclusions for them.
* m4/japhar_grep_cflags.m4 (JAPHAR_GREP_CFLAGS): Remove.
* configure.ac: Call pam_WARN_LANG_FLAGS.  Remove all uses
of JAPHAR_GREP_CFLAGS.

4 files changed, 118 insertions, 16 deletions

diff --git a/m4/.gitignore b/m4/.gitignore
index 24d81e43..4cbba3eb 100644
--- a/m4/.gitignore
+++ b/m4/.gitignore
@@ -5,3 +5,5 @@
 !ld-no-undefined.m4
 !ld-O1.m4
 !libprelude.m4
+!warnings.m4
+!warn_lang_flags.m4
diff --git a/m4/japhar_grep_cflags.m4 b/m4/japhar_grep_cflags.m4
index d0b05f07..4e8c4598 100644
--- a/m4/japhar_grep_cflags.m4
+++ b/m4/japhar_grep_cflags.m4
@@ -1,20 +1,4 @@
 dnl
-dnl JAPHAR_GREP_CFLAGS(flag, cmd_if_missing, cmd_if_present)
-dnl
-dnl From Japhar.  Report changes to japhar@hungry.com
-dnl
-AC_DEFUN([JAPHAR_GREP_CFLAGS],
-[case "$CFLAGS" in
-"$1" | "$1 "* | *" $1" | *" $1 "* )
-  ifelse($#, 3, [$3], [:])
-  ;;
-*)
-  $2
-  ;;
-esac
-])
-
-dnl
 dnl Test for __attribute__ ((unused))
 dnl Based on code from the tcpdump version 3.7.2 source.
 dnl
diff --git a/m4/warn_lang_flags.m4 b/m4/warn_lang_flags.m4
new file mode 100644
index 00000000..94b69af1
--- /dev/null
+++ b/m4/warn_lang_flags.m4
@@ -0,0 +1,31 @@
+#!/usr/bin/m4
+
+AC_DEFUN([pam_WARN_LANG_FLAGS], [dnl
+gl_WARN_ADD([-W])
+gl_WARN_ADD([-Wall])
+gl_WARN_ADD([-Wbad-function-cast])
+gl_WARN_ADD([-Wcast-align])
+gl_WARN_ADD([-Wcast-qual])
+gl_WARN_ADD([-Wdeprecated])
+gl_WARN_ADD([-Winline])
+gl_WARN_ADD([-Wmain])
+gl_WARN_ADD([-Wmissing-declarations])
+gl_WARN_ADD([-Wmissing-prototypes])
+gl_WARN_ADD([-Wp64])
+gl_WARN_ADD([-Wpointer-arith])
+gl_WARN_ADD([-Wreturn-type])
+gl_WARN_ADD([-Wshadow])
+gl_WARN_ADD([-Wstrict-prototypes])
+gl_WARN_ADD([-Wuninitialized])
+gl_WARN_ADD([-Wwrite-strings])
+AC_ARG_ENABLE([Werror],
+  [AS_HELP_STRING([--enable-Werror], [turn on -Werror compiler option])],
+  [case $enableval in
+     yes) gl_WARN_ADD([-Werror]) ;;
+     no)  ;;
+     *)   AC_MSG_ERROR([bad value $enableval for Werror option]) ;;
+   esac])
+AS_VAR_PUSHDEF([pam_WARN_FLAGS], [WARN_[]_AC_LANG_PREFIX[]FLAGS])dnl
+AC_SUBST(pam_WARN_FLAGS)
+AS_VAR_POPDEF([pam_WARN_FLAGS])dnl
+])
diff --git a/m4/warnings.m4 b/m4/warnings.m4
new file mode 100644
index 00000000..628627d0
--- /dev/null
+++ b/m4/warnings.m4
@@ -0,0 +1,85 @@
+# warnings.m4 serial 11
+# modified for strace project
+dnl Copyright (C) 2008-2013 Free Software Foundation, Inc.
+dnl This file is free software; the Free Software Foundation
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+dnl From Simon Josefsson
+
+# gl_AS_VAR_APPEND(VAR, VALUE)
+# ----------------------------
+# Provide the functionality of AS_VAR_APPEND if Autoconf does not have it.
+m4_ifdef([AS_VAR_APPEND],
+[m4_copy([AS_VAR_APPEND], [gl_AS_VAR_APPEND])],
+[m4_define([gl_AS_VAR_APPEND],
+[AS_VAR_SET([$1], [AS_VAR_GET([$1])$2])])])
+
+
+# gl_COMPILER_OPTION_IF(OPTION, [IF-SUPPORTED], [IF-NOT-SUPPORTED],
+#                       [PROGRAM = AC_LANG_PROGRAM()])
+# -----------------------------------------------------------------
+# Check if the compiler supports OPTION when compiling PROGRAM.
+#
+# FIXME: gl_Warn must be used unquoted until we can assume Autoconf
+# 2.64 or newer.
+AC_DEFUN([gl_COMPILER_OPTION_IF],
+[AS_VAR_PUSHDEF([gl_Flags], _AC_LANG_PREFIX[]FLAGS)dnl
+AS_VAR_PUSHDEF([gl_Warn], [gl_cv_warn_[]gl_Flags[]_$1])dnl
+AS_LITERAL_IF([$1],
+  [m4_pushdef([gl_Positive], m4_bpatsubst([$1], [^-Wno-], [-W]))],
+  [gl_positive="$1"
+case $gl_positive in
+  -Wno-*) gl_positive=-W`expr "X$gl_positive" : 'X-Wno-\(.*\)'` ;;
+esac
+m4_pushdef([gl_Positive], [$gl_positive])])dnl
+AC_CACHE_CHECK([whether $[]_AC_CC[] handles $1], m4_defn([gl_Warn]), [
+  gl_save_compiler_FLAGS="$gl_Flags"
+  gl_AS_VAR_APPEND(m4_defn([gl_Flags]),
+    [" $gl_unknown_warnings_are_errors ]m4_defn([gl_Positive])["])
+  AC_LINK_IFELSE([m4_default([$4], [AC_LANG_PROGRAM([])])],
+                 [AS_VAR_SET(gl_Warn, [yes])],
+                 [AS_VAR_SET(gl_Warn, [no])])
+  gl_Flags="$gl_save_compiler_FLAGS"
+])
+AS_VAR_IF(gl_Warn, [yes], [$2], [$3])
+m4_popdef([gl_Positive])dnl
+AS_VAR_POPDEF([gl_Flags])dnl
+AS_VAR_POPDEF([gl_Warn])dnl
+])
+
+# gl_UNKNOWN_WARNINGS_ARE_ERRORS
+# ------------------------------
+# Clang doesn't complain about unknown warning options unless one also
+# specifies -Wunknown-warning-option -Werror.  Detect this.
+AC_DEFUN([gl_UNKNOWN_WARNINGS_ARE_ERRORS],
+[AS_IF([test x${gl_unknown_warnings_are_errors+set} = x],
+  [gl_COMPILER_OPTION_IF([-Werror -Wunknown-warning-option],
+    [gl_unknown_warnings_are_errors='-Wunknown-warning-option -Werror'],
+    [gl_unknown_warnings_are_errors=])
+  ])
+])
+
+# gl_WARN_ADD(OPTION, [VARIABLE = WARN_[]_AC_LANG_PREFIX[]FLAGS],
+#             [PROGRAM = AC_LANG_PROGRAM()])
+# ---------------------------------------------
+# Adds parameter to WARN_[]_AC_LANG_PREFIX[]FLAGS if the compiler supports it
+# when compiling PROGRAM.  For example, gl_WARN_ADD([-Wparentheses]).
+#
+# If VARIABLE is a variable name, AC_SUBST it.
+AC_DEFUN([gl_WARN_ADD],
+[AS_VAR_PUSHDEF([gl_WARN_FLAGS], [WARN_[]_AC_LANG_PREFIX[]FLAGS])dnl
+gl_UNKNOWN_WARNINGS_ARE_ERRORS
+gl_COMPILER_OPTION_IF([$1],
+  [gl_AS_VAR_APPEND(m4_if([$2], [], [gl_WARN_FLAGS], [[$2]]), [" $1"])],
+  [],
+  [$3])
+m4_ifval([$2],
+         [AS_LITERAL_IF([$2], [AC_SUBST([$2])])],
+         [AC_SUBST(gl_WARN_FLAGS)])dnl
+AS_VAR_POPDEF([gl_WARN_FLAGS])dnl
+])
+
+# Local Variables:
+# mode: autoconf
+# End: